MSXML 6SP2で SQL Server 2005 のセットアップが失敗

Set objWMIOS = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set colResults = objWMIOS.ExecQuery("Select * from Win32_OperatingSystem",,48)

For Each objItem in colResults
  strOSVer = objItem.Version
Next

if strOSVer = OS then
  Wscript.Echo "=> OS version = " & strOSVer
else
  Wscript.Echo "   Error: OS version = " & strOSVer & " expected = " & OS
  Wscript.Quit -1
end if

if not (objWMIOS is nothing) then set objWMIOS = nothing
if not (colResults is nothing) then set colResults = nothing

Set objShell = CreateObject("WScript.Shell")
strTempPath = objShell.ExpandEnvironmentStrings("%Temp%")
strMSPPath = objShell.CurrentDirectory & MSPName

if not (objShell is nothing) then set objShell = nothing
strCodeMSXML = ""
Set objRegWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
objRegWMI.EnumKey HKLM, KeyPath, arrayRegKeys

For Each strKey in arrayRegKeys
  objRegWMI.GetStringValue HKLM, KeyPath & "\" & strKey, "DisplayName", strVal
  if InStr(strVal, MSXMLName) <> 0 then
    Wscript.Echo "=> Product code: " & strKey
    Wscript.Echo "=> Product name: " & strVal
    strCodeMSXML = strKey
  End If
Next

if not (objRegWMI is nothing) then set objRegWMI = nothing
if strCodeMSXML = "" Then
  Wscript.Echo "   Error: " & MSXMLName & " cannot be found"
  Wscript.Quit -1
end if

strExec = "MSIEXEC /X " & strCodeMSXML & " PATCH=""" & strMSPPath & """ /qn /l*v " & strTempPath & "\" & LOGFileName
Set objWMIService = GetObject("winmgmts:\\.\root\cimv2:Win32_Process")
errReturn = objWMIService.Create(strExec, null, null, PID)

if not (objWMIService is nothing) then set objWMIService = nothing
if errReturn <> 0 Then
  Wscript.Echo "   Error: " & strExec
  Wscript.Quit -2
end if

Wscript.Echo "=> Command: " & strExec
Wscript.Echo "=> PID: " & PID

Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colProcesses = objWMIService.ExecQuery("Select * from Win32_Process Where ProcessID = " & PID )

do while colProcesses.Count>0
  Wscript.Sleep(3000)
  Set colProcesses = objWMIService.ExecQuery("Select * from Win32_Process Where ProcessID = " & PID )
loop

if not (objWMIService is nothing) then set objWMIService = nothing
if not (colPprocesses is nothing) then set colPprocesses = nothing

strCodeMSXML = ""

Set objRegWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
objRegWMI.EnumKey HKLM, KeyPath, arrayRegKeys
For Each strKey in arrayRegKeys
  objRegWMI.GetStringValue HKLM, KeyPath & "\" & strKey, "DisplayName", strVal
  if InStr(strVal, MSXMLName) <> 0 then
    strCodeMSXML = strKey
  End If
Next

if not (objRegWMI is nothing) then set objRegWMI = nothing
if strCodeMSXML = "" Then
  Wscript.Echo "=> " & MSXMLName & " has been uninstalled"
else
  Wscript.Echo "   Error: please check log file: " & strTempPath & "\" & LOGFileName
  WScript.Echo
  Wscript.Quit -3
end if